Примеры по языку Перфолента.Net

Пример программы на языке программирования Перфолента.Net:

//Этот пример на языке программирования Перфолента.Net
//демонстрирует работу с ресурсами загружаемыми в EXE файл во время компиляции.
//Во время выполнения файлы можно извлечь в оперативную память и использовать по назначению.

//загрузим в ЕХЕ-шник 3 файла ресурсов
#Ресурс "Розы.jpg"
#Ресурс "ФайлНастроек.txt"
#Ресурс "ТабличныйДокумент.xlsx"
#Ресурс "no.wav"

//***************************
#ИспользоватьСтандартнуюБиблиотеку
Программа ПримерРаботыСРесурсами
    //---------------------------
    Процедура Старт
    
        // загружаем файл из ресурсов в объект ДвоичныеДанные   
        ДД = Новый ДвоичныеДанные(ПолучитьРесурс("ФайлНастроек.txt"))
        //посмотрим тип объекта
        ВыводСтроки "тип: "+ТипЗнчСтр(ДД)
        //посмотрим первый байт двоичных данных
        ВыводСтроки ДД.Буфер[0]
        
        //теперь загрузим тот же файл как массив байтов и посмотрим, что загрузилось
        МБ = ПолучитьРесурс("ФайлНастроек.txt").ВМассивБайтов
        ВыводСтроки "тип: "+ТипЗнчСтр(МБ)
        ВыводСтроки МБ[0]
        
        //теперь загрузим тот же файл как текстовый документ и выведем на экран
        ТД = Новый ТекстовыйДокумент
        ТД.ПрочитатьИзПотока(ПолучитьРесурс("ФайлНастроек.txt"))
        ВыводСтроки ТД
 
        //Откроем шаблон книги Эксель из ресурсов, заполним его и сохраним в файл 
        ТабДок = Новый ТабличныйДокумент
        ТабДок.ПрочитатьИзПотока(ПолучитьРесурс("ТабличныйДокумент.xlsx"))
        ТабДок.УстановитьЗначениеЯчейки(1,1,"ПРИВЕТ МИР!!! Я ЗДЕСЬ!!!") 
        ТабДок.Записать(ЭтаПрограмма.Каталог+"ПолучитьРесурс_Книга.xlsx") 
 
        //сыграем музычку из ресурса
        Новый Звук.ПлеерWAV(ПолучитьРесурс("no.wav")).ВоспроизвестиСинхронно
        //или так
        ПЛ = Новый Звук.ПлеерWAV
        ПЛ.ЗагрузитьИзРесурса("no.wav")
        ПЛ.Воспроизвести
        //ПЛ.ВоспроизвестиЦиклично //если это фоновая музыка
        
        //загрузим из ресурсов картинку
        Розы = Новый Картинка(ПолучитьРесурс("Розы.jpg"))
        
        //посмотрим картинку
        ф = Новый ОбычныеФормы.Форма
        ф.BackgroundImage = Розы
        ф.ОткрытьМодально
        
        ВыводСтроки "Готово"
        ВводСтроки
        
    КонецПроцедуры
    
КонецПрограммы    

К началу статьи