Пример «Реализация функции ВыборДля»

Файлы:

Пример программы на языке программирования Перфо:

//Эта программа написана на языке программирования Перфо
//для демонстрации написания функций 

//*******************************************
//пример реализации функции ВыборДля
//с помощью операторов Код и Вычислить
//*******************************************

//---------------------
// 1) напишем функцию  

(Функция (ВыборДля Значение1 СписокДействий) 
    //функцию Когда определяем внутри, что бы она видела Значение1
    (Функция (Когда Значение2 Действие)
        (Если (= Значение1 Значение2) (Вычислить Действие))
    )                               
    //вычислим каждое действие из списка
    (ПоКаждому (Функ(В)(Вычислить В)) СписокДействий) 
) 


//--------------------
// 2) создадим необходимые переменные

(Перем Доб " + добавка") //проверим, что внешняя переменная Доб будет вычислена внутри функции ВыборДля
(Перем Рез "")           //значение этой переменной установится внутри функции ВыборДля, а прочитаем мы её значение снаружи

//--------------------
// 3) тест

(Для (Инд 1 5) //повторим 5 раз. На 4-м и 5-м проходах срабатывает последний пункт оператора ВыборДля 
               //который можно считать секцией Иначе
               
    (Вывод пс "Проход № " Инд пс)    
    
    //делаем выбор по значению переменной Инд
    (ВыборДля Инд (Код
    (Когда 1 
        (Код (Уст Рез "111")(Вывод Рез Доб пс)))
    (Когда 2 
        (Код (Уст Рез "222")(Вывод Рез Доб пс)))
    (Когда 3 
        (Код (Уст Рез "333")(Вывод Рез Доб пс)))
        
    (Когда Инд //это как бы секция Иначе 
        (Код (Уст Рез (& Инд Инд Инд))(Вывод "еще " Рез Доб пс)))
    ))
    
    //проверим, что значение переменной Рез установилось верно
    (Вывод "Результат = " Рез пс)

) 

К началу статьи