Пример «Температура процессора»

Файлы:

Пример программы на языке программирования Перфо:

//Эта программа написана на языке Перфо
//для измерения температуры процессора
//с помощью встроенных датчиков температуры

//к сожалению, это работает не на всех компьютерах...
//в моём случае на домашнем сервере работало, а на рабочем ноутбуке нет...

//существует ли в вашем компьютере этот класс WMI и значения его свойств
//можно посмотреть через программу "Обозреватель WMI", которую можно найти в меню Сервис....

(Перем Компьютер (. (Новый СистемнаяИнформация) ИмяКомпьютера))
(Перем ПространствоИмен "ROOT\WMI")
(Перем Класс "MSAcpi_ThermalZoneTemperature")
(Перем Запрос "SELECT * FROM MSAcpi_ThermalZoneTemperature")

(Вывод пс)
(Вывод "=====================================" пс)
(Вывод "Компьютер:         " Компьютер пс)
(Вывод "Пространство имен: " ПространствоИмен пс)
(Вывод "Класс:             " Класс пс)
(Вывод "Запрос:            " Запрос пс)
(Вывод "=====================================" пс)
(Вывод пс)

(Перем масОбъекты (WMI.ПолучитьОбъектыКласса ПространствоИмен Класс))
(ДляКаждого (Струк масОбъекты)
    (Вывод "Свойства класса:" пс)
    (ДляКаждого (Свойство Струк)
        (Если (ЭтоМассив (Свойство.Значение))
            (Вывод (Свойство.Ключ) ": " (. (Свойство.Значение) Представление "; ") пс)
            (Вывод (Свойство.Ключ) ": " (Свойство.Значение) пс)
        )
    )
    (Вывод пс)
    (Вывод "Предельная температура, С = " (Окр (-(/(Струк.Получить "CriticalTripPoint") 10) 273.15) 2) пс)
    (Вывод "Текущая температура, С    = " (Окр (-(/(Струк.Получить "CurrentTemperature") 10) 273.15) 2) пс)
)

К началу статьи