Пример «Используем скрипт Перфо в Перфоленте»

Файлы:

Пример программы на языке программирования Перфолента.Net:

//Эта программа написана на языке программирования Перфолента.Net

// Этот пример показывает как использовать язык Перфо 
// для настройки объекта программы написанной на языке Перфолента


#ТипСборки КонсольноеПриложение
#ИспользоватьСтандартнуюБиблиотеку
ИмпортИмён Промкод.Перфолента.Консоль

//в данном случае загружаем сборку интерпретатора Перфо,
//который должен находиться в том же каталоге,
//но ни что не мешает вам встроить интерпретатор в программу как класс
#ЗагрузитьСборку "Перфо.exe"

//***************************
//Внутри скрипта Перфо мы настроим этот объект
Класс ОбъектМоейПрограммы
    
    &ВидноВсем Поле ПолеОбъекта тип Целое  
    &ВидноВсем Свойство СвойствоОбъекта тип Строка  
    Поле Результат тип Строка
    
    //---------------------------
    &ВидноВсем 
    Процедура НастроитьРезультат() 
        Результат=СвойствоОбъекта+ПолеОбъекта
    КонецПроцедуры    
    
    //---------------------------
    &ВидноВсем 
    Функция ВыводРезультата() тип Строка 
        Возврат Результат
    КонецФункции    
    
КонецКласса


//***************************
Программа ИспользуемСкриптПерфо
    //---------------------------
    Процедура Старт

        Скрипт = @"
        //включим отладку, что бы получать сообщения об ошибках
        (отладка истина) 
        
        //зададим значения переменных
        (перем А 8)
        (перем Б 9)
        
        //создадим функцию
        (функция (Квадро х) (* х х))
        
        //вычислим выражение с только что определенной функцией
        //и привоим результат полю объекта
        (Уст ЭтотОбъект.ПолеОбъекта (* 10 (Квадро (+ А Б))))
        
        //установим значение свойству объекта 
        (Уст ЭтотОбъект.СвойствоОбъекта "Результат = ")
        
        (ЭтотОбъект.НастроитьРезультат)
        
        //интерпретатор вернет последнее вычисленное значение
        "Скрипт выполнен!!!"
        
        "@

        //интерпретатор Перфо вернет строку результата 
        //или сообщение об ошибке, если отладка включена
        //или Неопределено, если отладка НЕ включена

        //создадим объект, который надо будет настроить в скрипте
        ОбъектНастройки = Новый ОбъектМоейПрограммы

        //передадим объект настройки в переменную ЭтотОбъект
        ВыводСтроки "Скрипт вернул: "+Перфо.ВыполнитьПрограмму(Скрипт, ОбъектНастройки)
        
        ВыводСтроки "Результат настройки объекта: "+ОбъектНастройки.ВыводРезультата
        
        Пауза


    КонецПроцедуры
    
КонецПрограммы    

К началу статьи